source: anuga_work/development/anugavis/m4/acx_pthread.m4 @ 5200

Last change on this file since 5200 was 5200, checked in by jack, 16 years ago

Some useful autoconf macros and basic structure.

File size: 10.7 KB
RevLine 
[5200]1##### http://autoconf-archive.cryp.to/acx_pthread.html
2#
3# SYNOPSIS
4#
5#   ACX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
6#
7# DESCRIPTION
8#
9#   This macro figures out how to build C programs using POSIX threads.
10#   It sets the PTHREAD_LIBS output variable to the threads library and
11#   linker flags, and the PTHREAD_CFLAGS output variable to any special
12#   C compiler flags that are needed. (The user can also force certain
13#   compiler flags/libs to be tested by setting these environment
14#   variables.)
15#
16#   Also sets PTHREAD_CC to any special C compiler that is needed for
17#   multi-threaded programs (defaults to the value of CC otherwise).
18#   (This is necessary on AIX to use the special cc_r compiler alias.)
19#
20#   NOTE: You are assumed to not only compile your program with these
21#   flags, but also link it with them as well. e.g. you should link
22#   with $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS
23#   $LIBS
24#
25#   If you are only building threads programs, you may wish to use
26#   these variables in your default LIBS, CFLAGS, and CC:
27#
28#          LIBS="$PTHREAD_LIBS $LIBS"
29#          CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
30#          CC="$PTHREAD_CC"
31#
32#   In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute
33#   constant has a nonstandard name, defines PTHREAD_CREATE_JOINABLE to
34#   that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
35#
36#   ACTION-IF-FOUND is a list of shell commands to run if a threads
37#   library is found, and ACTION-IF-NOT-FOUND is a list of commands to
38#   run it if it is not found. If ACTION-IF-FOUND is not specified, the
39#   default action will define HAVE_PTHREAD.
40#
41#   Please let the authors know if this macro fails on any platform, or
42#   if you have any other suggestions or comments. This macro was based
43#   on work by SGJ on autoconf scripts for FFTW (http://www.fftw.org/)
44#   (with help from M. Frigo), as well as ac_pthread and hb_pthread
45#   macros posted by Alejandro Forero Cuervo to the autoconf macro
46#   repository. We are also grateful for the helpful feedback of
47#   numerous users.
48#
49# LAST MODIFICATION
50#
51#   2007-07-29
52#
53# COPYLEFT
54#
55#   Copyright (c) 2007 Steven G. Johnson <stevenj@alum.mit.edu>
56#
57#   This program is free software: you can redistribute it and/or
58#   modify it under the terms of the GNU General Public License as
59#   published by the Free Software Foundation, either version 3 of the
60#   License, or (at your option) any later version.
61#
62#   This program is distributed in the hope that it will be useful, but
63#   WITHOUT ANY WARRANTY; without even the implied warranty of
64#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
65#   General Public License for more details.
66#
67#   You should have received a copy of the GNU General Public License
68#   along with this program. If not, see
69#   <http://www.gnu.org/licenses/>.
70#
71#   As a special exception, the respective Autoconf Macro's copyright
72#   owner gives unlimited permission to copy, distribute and modify the
73#   configure scripts that are the output of Autoconf when processing
74#   the Macro. You need not follow the terms of the GNU General Public
75#   License when using or distributing such scripts, even though
76#   portions of the text of the Macro appear in them. The GNU General
77#   Public License (GPL) does govern all other use of the material that
78#   constitutes the Autoconf Macro.
79#
80#   This special exception to the GPL applies to versions of the
81#   Autoconf Macro released by the Autoconf Macro Archive. When you
82#   make and distribute a modified version of the Autoconf Macro, you
83#   may extend this special exception to the GPL to apply to your
84#   modified version as well.
85
86AC_DEFUN([ACX_PTHREAD], [
87AC_REQUIRE([AC_CANONICAL_HOST])
88AC_LANG_SAVE
89AC_LANG_C
90acx_pthread_ok=no
91
92# We used to check for pthread.h first, but this fails if pthread.h
93# requires special compiler flags (e.g. on True64 or Sequent).
94# It gets checked for in the link test anyway.
95
96# First of all, check if the user has set any of the PTHREAD_LIBS,
97# etcetera environment variables, and if threads linking works using
98# them:
99if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
100        save_CFLAGS="$CFLAGS"
101        CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
102        save_LIBS="$LIBS"
103        LIBS="$PTHREAD_LIBS $LIBS"
104        AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])
105        AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)
106        AC_MSG_RESULT($acx_pthread_ok)
107        if test x"$acx_pthread_ok" = xno; then
108                PTHREAD_LIBS=""
109                PTHREAD_CFLAGS=""
110        fi
111        LIBS="$save_LIBS"
112        CFLAGS="$save_CFLAGS"
113fi
114
115# We must check for the threads library under a number of different
116# names; the ordering is very important because some systems
117# (e.g. DEC) have both -lpthread and -lpthreads, where one of the
118# libraries is broken (non-POSIX).
119
120# Create a list of thread flags to try.  Items starting with a "-" are
121# C compiler flags, and other items are library names, except for "none"
122# which indicates that we try without any flags at all, and "pthread-config"
123# which is a program returning the flags for the Pth emulation library.
124
125acx_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
126
127# The ordering *is* (sometimes) important.  Some notes on the
128# individual items follow:
129
130# pthreads: AIX (must check this before -lpthread)
131# none: in case threads are in libc; should be tried before -Kthread and
132#       other compiler flags to prevent continual compiler warnings
133# -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
134# -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
135# lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
136# -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
137# -pthreads: Solaris/gcc
138# -mthreads: Mingw32/gcc, Lynx/gcc
139# -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
140#      doesn't hurt to check since this sometimes defines pthreads too;
141#      also defines -D_REENTRANT)
142#      ... -mt is also the pthreads flag for HP/aCC
143# pthread: Linux, etcetera
144# --thread-safe: KAI C++
145# pthread-config: use pthread-config program (for GNU Pth library)
146
147case "${host_cpu}-${host_os}" in
148        *solaris*)
149
150        # On Solaris (at least, for some versions), libc contains stubbed
151        # (non-functional) versions of the pthreads routines, so link-based
152        # tests will erroneously succeed.  (We need to link with -pthreads/-mt/
153        # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
154        # a function called by this macro, so we could check for that, but
155        # who knows whether they'll stub that too in a future libc.)  So,
156        # we'll just look for -pthreads and -lpthread first:
157
158        acx_pthread_flags="-pthreads pthread -mt -pthread $acx_pthread_flags"
159        ;;
160esac
161
162if test x"$acx_pthread_ok" = xno; then
163for flag in $acx_pthread_flags; do
164
165        case $flag in
166                none)
167                AC_MSG_CHECKING([whether pthreads work without any flags])
168                ;;
169
170                -*)
171                AC_MSG_CHECKING([whether pthreads work with $flag])
172                PTHREAD_CFLAGS="$flag"
173                ;;
174
175                pthread-config)
176                AC_CHECK_PROG(acx_pthread_config, pthread-config, yes, no)
177                if test x"$acx_pthread_config" = xno; then continue; fi
178                PTHREAD_CFLAGS="`pthread-config --cflags`"
179                PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
180                ;;
181
182                *)
183                AC_MSG_CHECKING([for the pthreads library -l$flag])
184                PTHREAD_LIBS="-l$flag"
185                ;;
186        esac
187
188        save_LIBS="$LIBS"
189        save_CFLAGS="$CFLAGS"
190        LIBS="$PTHREAD_LIBS $LIBS"
191        CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
192
193        # Check for various functions.  We must include pthread.h,
194        # since some functions may be macros.  (On the Sequent, we
195        # need a special flag -Kthread to make this header compile.)
196        # We check for pthread_join because it is in -lpthread on IRIX
197        # while pthread_create is in libc.  We check for pthread_attr_init
198        # due to DEC craziness with -lpthreads.  We check for
199        # pthread_cleanup_push because it is one of the few pthread
200        # functions on Solaris that doesn't have a non-functional libc stub.
201        # We try pthread_create on general principles.
202        AC_TRY_LINK([#include <pthread.h>],
203                    [pthread_t th; pthread_join(th, 0);
204                     pthread_attr_init(0); pthread_cleanup_push(0, 0);
205                     pthread_create(0,0,0,0); pthread_cleanup_pop(0); ],
206                    [acx_pthread_ok=yes])
207
208        LIBS="$save_LIBS"
209        CFLAGS="$save_CFLAGS"
210
211        AC_MSG_RESULT($acx_pthread_ok)
212        if test "x$acx_pthread_ok" = xyes; then
213                break;
214        fi
215
216        PTHREAD_LIBS=""
217        PTHREAD_CFLAGS=""
218done
219fi
220
221# Various other checks:
222if test "x$acx_pthread_ok" = xyes; then
223        save_LIBS="$LIBS"
224        LIBS="$PTHREAD_LIBS $LIBS"
225        save_CFLAGS="$CFLAGS"
226        CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
227
228        # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
229        AC_MSG_CHECKING([for joinable pthread attribute])
230        attr_name=unknown
231        for attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
232            AC_TRY_LINK([#include <pthread.h>], [int attr=$attr; return attr;],
233                        [attr_name=$attr; break])
234        done
235        AC_MSG_RESULT($attr_name)
236        if test "$attr_name" != PTHREAD_CREATE_JOINABLE; then
237            AC_DEFINE_UNQUOTED(PTHREAD_CREATE_JOINABLE, $attr_name,
238                               [Define to necessary symbol if this constant
239                                uses a non-standard name on your system.])
240        fi
241
242        AC_MSG_CHECKING([if more special flags are required for pthreads])
243        flag=no
244        case "${host_cpu}-${host_os}" in
245            *-aix* | *-freebsd* | *-darwin*) flag="-D_THREAD_SAFE";;
246            *solaris* | *-osf* | *-hpux*) flag="-D_REENTRANT";;
247        esac
248        AC_MSG_RESULT(${flag})
249        if test "x$flag" != xno; then
250            PTHREAD_CFLAGS="$flag $PTHREAD_CFLAGS"
251        fi
252
253        LIBS="$save_LIBS"
254        CFLAGS="$save_CFLAGS"
255
256        # More AIX lossage: must compile with xlc_r or cc_r
257        if test x"$GCC" != xyes; then
258          AC_CHECK_PROGS(PTHREAD_CC, xlc_r cc_r, ${CC})
259        else
260          PTHREAD_CC=$CC
261        fi
262else
263        PTHREAD_CC="$CC"
264fi
265
266AC_SUBST(PTHREAD_LIBS)
267AC_SUBST(PTHREAD_CFLAGS)
268AC_SUBST(PTHREAD_CC)
269
270# Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
271if test x"$acx_pthread_ok" = xyes; then
272        ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
273        :
274else
275        acx_pthread_ok=no
276        $2
277fi
278AC_LANG_RESTORE
279])dnl ACX_PTHREAD
Note: See TracBrowser for help on using the repository browser.